diff --git a/sys-apps/attr/attr-2.4.38.ebuild b/sys-apps/attr/attr-2.4.38.ebuild
new file mode 100644
--- /dev/null
+++ b/sys-apps/attr/attr-2.4.38.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/attr-2.4.38.ebuild,v 1.2 2007/06/13 23:34:07 vapier Exp $
+
+inherit eutils autotools toolchain-funcs
+
+MY_P="${PN}_${PV}-1"
+DESCRIPTION="Extended attributes tools"
+HOMEPAGE="http://oss.sgi.com/projects/xfs/"
+SRC_URI="ftp://oss.sgi.com/projects/xfs/download/cmd_tars/${MY_P}.tar.gz
+	ftp://xfs.org/mirror/SGI/cmd_tars/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="nls"
+
+DEPEND="nls? ( sys-devel/gettext )
+	sys-devel/autoconf"
+RDEPEND=""
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-2.4.24-only-symlink-when-needed.patch
+	epatch "${FILESDIR}"/${PN}-2.4.38-LDFLAGS.patch
+	sed -i \
+		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
+		-e '/HAVE_ZIPPED_MANPAGES/s:=.*:=false:' \
+		include/builddefs.in \
+		|| die "failed to update builddefs"
+	eautoconf
+}
+
+src_compile() {
+	export OPTIMIZER=${CFLAGS}
+	export DEBUG=-DNDEBUG
+
+	econf \
+		$(use_enable nls gettext) \
+		--libexecdir=/usr/$(get_libdir) \
+		--bindir=/bin \
+		|| die
+	emake || die
+}
+
+src_install() {
+	emake DIST_ROOT="${D}" install install-lib install-dev || die
+	# the man-pages packages provides the man2 files
+	rm -r "${D}"/usr/share/man/man2
+	prepalldocs
+
+	# move shared libs to /
+	dodir /$(get_libdir)
+	mv "${D}"/usr/$(get_libdir)/libattr.so* "${D}"/$(get_libdir)/ || die
+	gen_usr_ldscript libattr.so
+}